Crea una instancia de Looker (Google Cloud Core) con conexiones seguras públicas

Console

1. Navega a la página del producto de Looker (Google Cloud Core) desde tu proyecto en la consola de Google Cloud. Si ya creaste una instancia de Looker (Google Cloud Core) en este proyecto, se abrirá la página Instancias.

   Ir a Looker (Google Cloud Core)

2. Haz clic en CREAR INSTANCIA.
3. En la sección Nombre de la instancia, proporciona un nombre para la instancia de Looker (Google Cloud Core). El nombre de la instancia no está asociado con la URL de la instancia de Looker (Google Cloud Core) una vez que se crea. El nombre de la instancia no se puede cambiar después de crearla.
4. En la sección Región, selecciona la opción adecuada del menú desplegable para alojar tu instancia de Looker (Google Cloud Core). Selecciona la región que coincida con la región del contrato de suscripción, que es donde se asigna la cuota de tu proyecto. Las regiones disponibles se enumeran en la página de documentación Ubicaciones de Looker (Google Cloud Core). No puedes cambiar la región una vez que se creó la instancia.

5. En la sección Edición, establece la edición de la instancia según las necesidades de tu organización. El tipo de edición afecta algunas de las funciones que están disponibles para la instancia. Asegúrate de elegir el mismo tipo de edición que se indica en tu contrato anual y de que tengas una cuota asignada para ese tipo de edición. Estas son las opciones de edición:

   • Estándar: Plataforma de Looker (Google Cloud Core) para organizaciones o equipos pequeños con menos de 50 usuarios
   • Enterprise: Plataforma de Looker (Google Cloud Core) con funciones de seguridad mejoradas para abordar una amplia variedad de casos de uso de IE interna y estadísticas
   • Embed: Plataforma de Looker (Google Cloud Core) para implementar y mantener estadísticas externas confiables y aplicaciones personalizadas a gran escala
   • Ediciones de no producción: Si deseas un entorno de etapa de pruebas y pruebas, selecciona una de las ediciones de no producción. Para obtener más información, consulta la documentación Instancias de no producción.
   • Ediciones de prueba: Una edición de prueba tiene la misma compatibilidad con funciones que su edición de producción correspondiente, con la excepción de que las ediciones de prueba son válidas por 90 días.

   Las ediciones no se pueden cambiar después de crear la instancia. Si deseas cambiar una edición, puedes usar la importación y la exportación para mover los datos de tu instancia de Looker (Google Cloud Core) a una instancia nueva que esté configurada con una edición diferente.

6. En la sección Personaliza tu instancia, haz clic en Mostrar opciones de configuración para mostrar un grupo de parámetros de configuración adicionales que puedes personalizar para la instancia.

7. En la sección Conexiones, selecciona Usar conexiones seguras públicas. Un parámetro de configuración de conexión segura pública asigna una dirección IP externa accesible a través de Internet y está disponible para todos los tipos de edición.

8. Si creas una instancia de edición Enterprise o Embed, verás la sección Encriptación. En la sección Encriptación, puedes seleccionar el tipo de encriptación que deseas usar en tu instancia. Están disponibles las siguientes opciones de encriptación:

   • Google-managed encryption key: Esta opción es la predeterminada y no requiere ninguna configuración adicional.
   • Clave de encriptación administrada por el cliente (CMEK): Consulta la página de documentación Usa claves de encriptación administradas por el cliente con Looker (Google Cloud Core) para obtener más información sobre las CMEK y cómo configurarlas durante la creación de la instancia. El tipo de encriptación no se puede cambiar después de crear la instancia.
   • Habilitar la encriptación validada de nivel 1 de FIPS 140-3: Consulta la página de documentación Habilita el cumplimiento del nivel 1 de FIPS 140-3 en una instancia de Looker (Google Cloud Core) para obtener más información sobre la compatibilidad con el nivel 1 de FIPS 140-3 en Looker (Google Cloud Core).

9. En la sección Canal de versiones, selecciona el canal de versiones que mejor se adapte a tus necesidades:

   • Rápido: Acceso más temprano a las funciones. Opción predeterminada recomendada para instancias de no producción.
   • Normal: Estabilidad equilibrada. Se recomienda para las instancias de producción.
   • Sin canal: Sin canal de versiones. Durante la versión preliminar, Sin canal es la opción predeterminada.

10. En la sección Período de mantenimiento, puedes especificar de forma opcional el día de la semana y la hora en que Looker (Google Cloud Core) programa el mantenimiento.

11. En la sección Período de mantenimiento denegado, puedes especificar de forma opcional un bloque de días en el que Looker (Google Cloud Core) no programa el mantenimiento. No puedes establecer un período de mantenimiento denegado si también inscribes la instancia en el canal de versiones rápido o usas la marca de configuración de aplicación de parches de seguridad acelerada (ASP) con el canal de versiones normal.

12. En la sección Gemini en Looker, puedes hacer que las funciones de Gemini en Looker estén disponibles para la instancia de Looker (Google Cloud Core). Para habilitar Gemini en Looker, selecciona Gemini y, luego, Funciones de Verificador de confianza. Cuando se habilita Funciones de Verificador de confianza, los usuarios pueden acceder a las capacidades de Verificador de confianza de Gemini en Looker. Puedes solicitar acceso a las capacidades privadas de Verificador de confianza a través del formulario de versión preliminar de Gemini en Looker por cada usuario. Debes habilitar este parámetro de configuración para usar Gemini durante la fase previa a la DG de la versión preliminar. De manera opcional, selecciona Uso de los datos de Verificador de confianza. Cuando se habilita este parámetro de configuración, aceptas que Google use tus datos como se describe en las condiciones del Google Cloud Programa de Verificadores de confianza de Gemini para inhabilitar Gemini para una instancia de Looker (Google Cloud Core), borra el parámetro de configuración Gemini.

13. En la sección Integración de Knowledge Catalog, puedes seleccionar de forma opcional la casilla de verificación Inhabilitar la integración de Knowledge Catalog si no deseas que Looker (Google Cloud Core) se integre con Knowledge Catalog. Looker (Google Cloud Core) y Knowledge Catalog se integran de forma predeterminada.

14. Haz clic en Crear.

gcloud

1. Si usas CMEK, entonces crea la cuenta de servicio de Looker y sigue las instrucciones para configurar CMEK primero.

2. Usa el comando gcloud looker instances create para crear la instancia:

   gcloud looker instances create INSTANCE_NAME \
   --project=PROJECT_ID \
   --region=REGION \
   --edition=EDITION \
   [--release-channel=RELEASE_CHANNEL]\
   --public-ip-enabled \
   --async
   

   Reemplaza lo siguiente:

   • INSTANCE_NAME: Es un nombre para tu instancia de Looker (Google Cloud Core). No está asociado con la URL de la instancia.
   • PROJECT_ID: Es el nombre del Google Cloud proyecto en el que creas la instancia de Looker (Google Cloud Core).
   • REGION: Es la región en la que se aloja tu instancia de Looker (Google Cloud Core). Selecciona la región que coincida con la región del contrato de suscripción. Las regiones disponibles se enumeran en la página de documentación Ubicaciones de Looker (Google Cloud Core). No puedes cambiar la región una vez que se creó la instancia.
   • EDITION: Es la edición, el tipo de entorno (producción o no producción) y si se trata de una edición de prueba para la instancia. Sus valores disponibles son core-standard-annual, core-enterprise-annual, core-embed-annual, nonprod-core-standard-annual, nonprod-core-enterprise-annual, nonprod-core-embed-annual, core-trial-standard, core-trial-enterprise y core-trial-embed. Las ediciones no se pueden cambiar después de crear la instancia. Si deseas cambiar una edición, puedes usar la importación y la exportación para mover los datos de tu instancia de Looker (Google Cloud Core) a una instancia nueva que esté configurada con una edición diferente.
   • RELEASE_CHANNEL: Es el canal de versiones de la instancia. Los valores disponibles son rapid, regular y no-channel. El valor predeterminado durante la versión preliminar es no-channel. Si no incluyes esta marca en tu comando create, la instancia se creará con el canal predeterminado. Esta función está en vista previa.

   También incluye estas marcas:

   • --public-ip-enabled se usa para habilitar la conexión segura pública.
   • Se recomienda --async cuando creas una instancia de Looker (Google Cloud Core).

3. Puedes agregar más parámetros para aplicar otros parámetros de configuración de la instancia:

   [--maintenance-window-day=MAINTENANCE_WINDOW_DAY
         --maintenance-window-time=MAINTENANCE_WINDOW_TIME]
   [--deny-maintenance-period-end-date=DENY_MAINTENANCE_PERIOD_END_DATE
         --deny-maintenance-period-start-date=DENY_MAINTENANCE_PERIOD_START_DATE
         --deny-maintenance-period-time=DENY_MAINTENANCE_PERIOD_TIME]
   [--kms-key=KMS_KEY_ID]
   [--accelerated-security-patch-enabled]
   [--no-accelerated-security-patch-enabled]
   [--fips-enabled]
   [--catalog-integration-enabled]
   [--no-catalog-integration-enabled]
   

   Reemplaza lo siguiente:

   • MAINTENANCE_WINDOW_DAY: Debe ser uno de los siguientes: friday, monday, saturday, sunday, thursday, tuesday, wednesday. Consulta la página de documentación Administra las políticas de mantenimiento para Looker (Google Cloud Core) para obtener más información sobre la configuración del período de mantenimiento.
   • MAINTENANCE_WINDOW_TIME y DENY_MAINTENANCE_PERIOD_TIME: Deben estar en hora UTC en formato de 24 horas (por ejemplo, 13:00, 17:45).
   • DENY_MAINTENANCE_PERIOD_START_DATE y DENY_MAINTENANCE_PERIOD_END_DATE: Deben estar en formato YYYY-MM-DD. No puedes establecer un período de mantenimiento denegado si también inscribes la instancia en el canal de versiones rápido o usas la marca de configuración de aplicación de parches de seguridad acelerada (ASP) con el canal de versiones normal.
   • KMS_KEY_ID: Debe ser la clave que se crea cuando se configuran las claves de encriptación administradas por el cliente (CMEK).

   Las siguientes marcas habilitan otros parámetros de configuración:

   • --accelerated-security-patch-enabled y --no-accelerated-security-patch-enabled: Incluye una de estas marcas si tu instancia está en el canal regular y deseas recibir o inhabilitar parches de seguridad cada dos semanas. Esta función está en vista previa.
   • --fips-enabled: Habilita el cumplimiento del nivel 1 de FIPS 140-3.
   • Reemplaza la marca --catalog-integration-enabled por la --no-catalog-integration-enabled marca para inhabilitar la integración de Looker (Google Cloud Core) y Knowledge Catalog. Esta función está en vista previa.

Terraform

Usa el siguiente recurso de Terraform para aprovisionar una instancia Standard de Looker (Google Cloud Core) con funcionalidad básica:

# Creates a Standard edition Looker (Google Cloud core) instance with basic functionality enabled.
resource "google_looker_instance" "main" {
  name             = "my-instance"
  platform_edition = "LOOKER_CORE_STANDARD"
  region           = "us-central1"
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

Usa el siguiente recurso de Terraform para aprovisionar una instancia Standard de Looker (Google Cloud Core) con parámetros de configuración adicionales aplicados:

# Creates a Standard edition Looker (Google Cloud core) instance with full functionality enabled.

resource "google_looker_instance" "main" {
  name              = "my-instance"
  platform_edition  = "LOOKER_CORE_STANDARD"
  region            = "us-central1"
  public_ip_enabled = true
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  // User metadata config is only available when platform edition is LOOKER_CORE_STANDARD.
  user_metadata {
    additional_developer_user_count = 10
    additional_standard_user_count  = 10
    additional_viewer_user_count    = 10
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

Usa el siguiente recurso de Terraform para aprovisionar una instancia Enterprise de Looker (Google Cloud Core) con una conexión de red privada:

# Creates an Enterprise edition Looker (Google Cloud core) instance with full, Private IP functionality.
resource "google_looker_instance" "main" {
  name               = "my-instance"
  platform_edition   = "LOOKER_CORE_ENTERPRISE_ANNUAL"
  region             = "us-central1"
  private_ip_enabled = true
  public_ip_enabled  = false
  reserved_range     = google_compute_global_address.main.name
  consumer_network   = data.google_compute_network.main.id
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  encryption_config {
    kms_key_name = google_kms_crypto_key.main.id
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
  depends_on = [
    google_service_networking_connection.main,
    google_kms_crypto_key.main
  ]
}

resource "google_kms_key_ring" "main" {
  name     = "keyring-example"
  location = "us-central1"
}

resource "google_kms_crypto_key" "main" {
  name     = "crypto-key-example"
  key_ring = google_kms_key_ring.main.id
}

resource "google_service_networking_connection" "main" {
  network                 = data.google_compute_network.main.id
  service                 = "servicenetworking.googleapis.com"
  reserved_peering_ranges = [google_compute_global_address.main.name]
}

resource "google_compute_global_address" "main" {
  name          = "looker-range"
  purpose       = "VPC_PEERING"
  address_type  = "INTERNAL"
  prefix_length = 20
  network       = data.google_compute_network.main.id
}

data "google_project" "main" {}

data "google_compute_network" "main" {
  name = "default"
}

resource "google_kms_crypto_key_iam_member" "main" {
  crypto_key_id = google_kms_crypto_key.main.id
  role          = "roles/cloudkms.cryptoKeyEncrypterDecrypter"
  member        = "serviceAccount:service-${data.google_project.main.number}@gcp-sa-looker.iam.gserviceaccount.com"
}

Si deseas obtener más información para aplicar o quitar una configuración de Terraform, consulta los comandos básicos de Terraform.

La creación de instancias no se puede pausar ni finalizar una vez que se inicia. Cuando tu recurso de Terraform se aprovisione correctamente, tu terminal imprimirá el siguiente mensaje:

Creation complete after XmXs [id=projects/PROJECT-ID/locations/REGION/instances/my-instance-randomly-generated-name]

Apply complete! Resources: X added, X changed, X destroyed.